DevelopmentModuleIntro

Dieser Text ist in Arbeit und muss noch an einigen Stellen ergänzt werden. Insbesondere beschreibt der Text derzeit nur einstufige Module. Die Abgrenzung zu zweistufigen Modulen und deren Eigenschaften sollte noch ergänzt werden.

Einleitung

Um neue Geräte, Dienste, o.ä. in FHEM verfügbar zu machen, kann man ein eigenes Modul in Perl schreiben. Ein Modul wird in FHEM automatisch geladen, wenn ein entsprechendes Device in FHEM definiert wird. Das Modul ermöglicht eine spezifische Kommunikation mit einem physikalischen Gerät, stellt Ergebnisse ("Readings") und Events innerhalb von FHEM zur Verfügung und erlaubt es, das Gerät mit "Set"-/"Get"-Befehlen zu beeinflussen. Dieser Artikel soll den Einstieg in die Entwicklung eigener Module erleichtern.

Mit dem FHEM-Befehl define werden Devices in FHEM basierend auf einem Modul definiert. Dieser Befehl sorgt dafür, dass ein neues Modul bei Bedarf geladen und initialisiert wird. Ein gutes Beispiel ist hierbei die zentrale Konfigurationsdatei "fhem.cfg" in der sämtliche Devices in Form von define-Statements gespeichert sind.

Damit das funktioniert müssen der Name des Moduls und der Name der Initialisierungsfunktion identisch sein. Das folgende Beispiel soll dies verdeutlichen:

Ein Jeelink USB-Stick könnte beispielsweise mit dem Befehl define JeeLink1 JeeLink /dev/ttyUSB0@57600 definiert werden.

In fhem.pl wird der define-Befehl verarbeitet und geprüft, ob ein Modul mit dem Namen "JeeLink" schon geladen ist und falls nicht ein Modul mit Namen XY_JeeLink.pm im Modulverzeichnis (z.B. /opt/fhem/FHEM) gesucht und dann geladen. Danach wird die Funktion JeeLink_Initialize() aufgerufen um das Modul in FHEM zu registrieren. Eine Moduldatei muss dazu eine Funktion <Modulname>_Initialize() enthalten. Durch den Aufruf dieser Funktion wird FHEM mitgeteilt, welche Funktionalitäten dieses Modul unterstützt.

In der Initialisierungsfunktion des Moduls werden die Namen aller weiteren Perl-Funktionen des Moduls, die von fhem.pl aus aufgerufen werden, bekannt gemacht. Dazu wird für jedes Modul ein eigener Hash (genauer "Modul-Hash") mit entsprechenden Werten gefüllt, der in fhem.pl für jedes Modul entsprechend abgelegt wird. Dadurch weiß FHEM wie dieses Modul anzusprechen ist.

Der Hash einer Geräteinstanz

Eine Besonderheit in Perl sind assoziative Arrays, (nicht ganz richtig als "Hash" bezeichnet) in denen die Adressierung nicht über eine Zählvariable erfolgt, sondern über einen beliebigen String. Die internen Abläufe bei der Adressierung führen dazu, dass die Speicherung in und der Abruf aus Hashes relativ langsam ist.

Der zentrale Speicherort für Informationen einer Geräteinstanz bei FHEM ist ein solcher Hash, der seinerseits in fhem.pl von einem globalen Hash referenziert wird.

$defs{Devicename} in fhem.pl verweist auf den Hash der Geräteinstanz. Diesen Verweis (also nur die Adresse) bekommen die Funktionen eines Moduls übergeben, das direkt von fhem.pl aufgerufen wird. In dem Hash stehen beispielsweise die internen Werte des Geräts, die im GUI als "Internals" angezeigt werden oder die Readings des Geräts. Beispiele:

$hash->{NAME} enthält den Namen der Geräteinstanz,
$hash->{TYPE} enthält die Typbezeichnung des Geräts
$hash->{INTERVAL} enthält ein Abfrageintervall

Ausführung von Modulen

FHEM führt Module normalerweise nicht parallel aus. Daher wäre es ungünstig wenn Module Werte von einem Gerät abfragen und dann auf die Antwort des Geräts warten. In dieser Zeit wäre der Rest von FHEM blockiert. Die Ein- und Ausgabe sollte ohne Blockieren erfolgen und die Verarbeitung mehrerer Ein- und Ausgabekanäle quasi parallel ermöglichen.

Dafür werden in FHEM zwei zentrale Listen gepflegt, in der die Filedeskriptoren der geöffneten Kommunikatonsverbindungen gespeichert sein können. Auf Linux- bzw. Unix-basierten Plattformen wird der select-Befehl des Betriebssystems verwendet und entsprechend gibt es in FHEM eine selectlist, in der die Filedeskriptoren der Geräedateien (z.B. /dev/ttyUSBx etc.) gespeichert sind.

In der zentralen Schleife von fhem.pl wird mit select überwacht, ob über eine der geöffneten Schnittstellen Daten zum Lesen anstehen. Wenn dies der Fall ist, dann wird die Lesefunktion (X_Read) des zuständigen Moduls aufgerufen, damit es die Daten entgegennimmt und die Schleife wird weiter ausgeführt.

Auf Windows-Systemen funktioniert dies anders. Hier können USB/Seriell-Geräte nicht per select überwacht werden. In FHEM unter Windows werden daher diese Schnittstellen kontinuierlich abgefragt ob Daten bereitstehen. Dafür müssen Module zusätzlich zur Lesefunktion eine Abfragefunktion (X_Ready) implementieren, die prüft ob Daten zum Lesen anstehen. Auch auf Linux/Unix-Plattformen hat diese Funktion eine Aufgabe. Falls nämlich eine Schnittstelle ausfällt beziehungsweise ein CUL oder USB-zu-Seriell Adapter ausgesteckt wird, dann wird über diese Funktion regelmäßig geprüft ob die Schnittstelle wieder verfügbar wird.

Innerhalb der eigentlichen Lesefunktion (X_Read) werden dann die Daten vom zugehörigen Gerät gelesen, das nötige Protokoll implementiert und Werte in Readings geschrieben.

Auch wenn von einem Anwender über ein get Daten aktiv von einem Gerät angefordert werden sollte nicht blockierend gewartet werden. Eine asynchrone Ausgabe ist über asyncOutput möglich. Siehe Beschreibung und Beispiel. Weitere Anwendungsbeispiele finden sich im PLEX Modul und im überarbeiteten und nicht-blockierenden SYSSTAT Modul.

Readings

Werte, die von einem Gerät gelesen werden und in FHEM zur Verfügung stehen werden Readings genannt. Sie werden als Unterstruktur des Hashes der jeweiligen Geräteinstanz gespeichert, beispielsweise

$hash->{READINGS}{Temp}{VAL} für die Temperatur eines Fühlers
$hash->{READINGS}{Temp}{TIME} für den Zeitstempel der Messung

Für den lesenden Zugriff auf Readings steht die Funktion ReadingsVal() zur Verfügung. Ein direkter Zugriff auf die Datenstruktur sollte nicht vorgenommen werden.

Readings werden im Statefile von FHEM automatisch auf der Festplatte zwischengespeichert, damit sie nach einem Neustart sofort wieder zur Verfügung stehen, auch bevor sie vom Modul neu gesetzt oder aktualisiert werden.

Readings, die mit einem Punkt im Namen beginnen, haben eine funktionale Besonderheit. Sie werden im FHEMWEB nicht angezeigt und können somit als "Permanentspeicher" innerhalb des Moduls genutzt werden. Um größere Datenmengen permanent zu speichern sollte man jedoch die Funktion setKeyValue() verwenden.

Zum Setzen von Readings sollen

bei Gruppen von Readings der Funktionsblock readingsBeginUpdate, readingsBulkUpdate (mehrfach wiederholt), readingsEndUpdate
bei einzelnen Updates die Funktion readingsSingleUpdate

aufgerufen werden. Dabei kann man auch angeben, ob dabei ein Event ausgelöst werden soll oder nicht. Events erzeugen spürbare Last auf dem System (siehe NotifyFn), das Ändern von Readings ohne dass dabei Events erzeugt werden jedoch nicht.

Eine Sequenz zum Setzen von Readings könnte folgendermaßen aussehen:

readingsBeginUpdate($hash);
readingsBulkUpdate($hash, $readingName1, $wert1 );
readingsBulkUpdate($hash, $readingName2, $wert2 );
readingsEndUpdate($hash, 1);

Internals

Werte, die das Modul intern als Teil des Hashes speichert, die aber keine Readings sind, nennt man Internals. Sie werden ebenfalls als Unterstruktur des Hashes der jeweiligen Geräteinstanz gespeichert, beispielswiese $hash->{INTERVAL} für ein Abfrageintervall, das beim Define-Befehl übergeben wurde und als Internal gespeichert wird. Internals werden jedoch im Gegensatz zu Readings nicht im statefile zwischengespeichert.

Falls Werte wie das gerade erwähnte Intervall nicht über den Define-Befehl gesetzt werden sollen und im Betrieb einfach änderbar sein sollen, ist eine alternative Möglichkeit die Speicherung in so genannten Attributen. Dann würde man den Define-Befehl so implementieren, dass er kein Intervall übergeben bekommt und statt dessen nach dem Define-Befehl zusätzlich den Befehl attr erwarten.

Generell werden alle Werte, welche direkt in der ersten Ebene von $hash gespeichert werden auf der Detail-Seite einer Definition in der FHEMWEB Oberfläche angezeigt. Es gibt jedoch Ausnahmen:

$hash->{helper}{URL] - Alle Elemente, welche als Unterelement wieder einen Hash besitzen werden nicht in FHEMWEB dargestellt. Typischerweise speichern Module Daten unter $hash->{helper} zwischen, die für den User nicht relevant sind, sondern nur der internen Verarbeitung dienen.
$hash->{.ELEMENT} - Alle Knoten, welche mit einem Punkt beginnen werdeb in der FHEMWEB Oberfläche nicht angezeigt. Man kann diese Daten jedoch beim Aufruf des list-Kommandos einsehen.

Es gibt bereits vorbelegte Internals welche in FHEM dazu dienen definitionsbezogene Informationen wie bspw. Namen, Attribute und Readings zu speichern. Dies sind im besonderen:

Internal	Beschreibung
`$hash->{NAME}`	Der Definitionsname mit dem die Definition angelegt wurde.
`$hash->{READINGS}`	Enthält alle aktuell vorhandenen Readings. Daten unterhalb dieses Knotens sollte man nicht direkt manipulieren. Um Readings zu Erzeugen gibt es entsprechende Reading-Funktionen.
`$hash->{NR}`	Die Positions-Nr der Definition innerhalb der Konfiguration. Diese dient dazu die Konfiguration in der gleichen Reihenfolge zu speichern, wie die einzelnen Definitionen angelegt wurden.
`$hash->{TYPE}`	Der Modulname mit welchem die Definition angelegt wurde.
`$hash->{DEF}`	Das erste Argument welches beim define-Befehl übergeben wurde. Auch wenn man mehr als ein Argument beim Define übergibt, wird hier nur das erste Argument in `$hash->{DEF}` gespeichert.
`$hash->{CFGFN}`	Der Dateiname der Konfigurationsdatei in der diese Definition enthalten ist (sofern nicht in fhem.cfg). Dieser Wert ist nur gefüllt, wenn man mit mehreren Konfigurationsdateien arbeitet die dann in fhem.cfg via include-Befehl eingebunden werden.
`$hash->{NTFY_ORDER}`	Sofern das Modul Events via NotifyFn verarbeitet enthält jede Definition eine Notify-Order als Zeichenkette bestehend aus dem Notify Order Prefix und dem Definitionsnamen. Details zur Funktionsweise gibt es in der Beschreibung zur Notify-Funktion im Abschnitt "Reihenfolge für den Aufruf der Notify-Funktion beeinflussen".
`$hash->{NOTIFYDEV}`	Sofern das Modul Events via NotifyFn verarbeitet kann man damit die Definitionen, von denen man Events erhalten will begrenzen. Details zur Funktionsweise gibt es in der Beschreibung zur Notify-Funktion im Abschnitt "Begrenzung der Aufrufe auf bestimmte Geräte".
`$hash->{IODev}`	Hier wird die zugeordnete IO-Definition gespeichert, welche für den Datentransport und -empfang dieser Definition zuständig ist. Dieser Wert existiert nur bei Modulen die nach dem zweistufigen Modulkonzept arbeiten.
`$hash->{CHANGED}`	Hier werden alle Events kurzzeitig gesammelt, welche für die Eventverarbeitung anstehen. Insbesondere die Reading-Funktionen speichern hier alle Events zwischen um sie nach Abschluss via DoTrigger() zu verarbeiten.
`$hash->{FD}`	Wenn die Definition eine Netzwerkverbindung oder serielle Schnittstelle geöffnet hat (via DevIo), so wird der entsprechende File-Deskriptor in diesem Internal gespeichert. Damit kann FHEM alle geöffneten Filedeskriptoren der entsprechenden Definition zuordnen um bei ankommenden Daten die Definition via Read-Funktion damit zu versorgen.

Generell sollte man die hier genannten systemweiten Internals nicht modifizieren, da ansonsten die korrekte Funktionsweise von FHEM nicht mehr garantiert werden kann.

Attribute

Parameter einer Definition können mit dem Befehl attr als so genannte Attribute gesetzt und damit dem Modul zur Verfügung gestellt werden. Attribute werden zusammen mit dem define-Statemant der Definition beim Speichern der aktuellen Konfiguration von FHEM in die Konfigurationsdatei geschrieben. Beim Neustart werden die entsprechenden Befehle ausgeführt um alle Definition inkl. Attribute wieder anzulegen. Zur Laufzeit werden Attribute in dem globalen Hash %attr mit dem Definitionsnamen als Index ($attr{$name}) gespeichert. Ein Attribut mit dem Namen header würde beispielsweise mit $attr{$name}{header} adressiert. Generell sollte %attr nicht durch direkten Zugriff manipuliert werden.

Zum Auslesen von Attributen sollte die Funktion AttrVal() verwendet werden.

Welche Attribute ein Modul unterstützt muss in der Funktion X_Initialize durch Setzen der Variable $hash->{AttrList} bekannt gemacht werden (siehe unten). Wenn beim Setzen von Attributen die Werte geprüft werden sollen oder zusätzliche Funktionalitäten implementiert werden müssen, dann muss dies in der Funktion X_Attr (siehe unten) implementiert werden.

Die wichtigsten Funktionen in einem Modul

Eine typische Grundfunktion eines einfachen Moduls ist das Auslesen von Werten von einem physischen Gerät und Bereitstellen dieser Werte innerhalb von FHEM als Readings. Das Geräte könnte beispielsweise an einem USB-Port angeschlossen sein. Folgende Funktionen könnte man beispielsweise in einem Modul mit Namen X implementieren:

X_Initialize (initialisiert das Modul und gibt de Namen der zusätzlichen Funktionen bekannt)
X_Define (wird beim define aufgerufen)
X_Undef (wird beim delete, sowie rereadcfg aufgerufen. Dient zum Abbau von offenen Verbindungen, Timern, etc.)
X_Delete (wird beim delete aufgerufen um das Gerät endgültig zu löschen)
X_Set (wird beim Befehl set aufgerufen um Daten an das Gerät zu senden)
X_Get (wird beim Befehl get aufgerufen um Daten vom Gerät abzufragen)
X_Attr (wird beim Befehl attr aufgerufen um beispielsweise Werte zu prüfen)
X_Read (wird vom globalen select aufgerufen, falls Daten zur Verfuegung stehen)
X_Parse (wird bei zweistufigen Modulen vom Dispatch aufgerufen und muss hier noch beschrieben werden)
X_Ready (wird unter windows als ReadFn-Erstatz benoetigt bzw. um zu pruefen, ob ein Geraet wieder eingesteckt ist)
X_Notify (falls man benachrichtigt werden will)
X_Rename (falls ein Gerät umbenannt wird)
X_Shutdown (wird beim Herunterfahren aufgeführt)

Die Funktionen werden im folgenden beschrieben (soweit diese Seite inzwischen vollständig ist):

X_Initialize

sub X_Initialize($)
{
	my ($hash) = @_;
	...

Das X im Namen muss dabei auf den Namen des Moduls bzw. des definierten Gerätetyps geändert werden. Im Modul mit der Datei 36_JeeLink.pm beispielsweise ist der Name der Funktion JeeLink_Initialize. Die Funktion wird von Fhem.pl nach dem Laden des Moduls aufgerufen und bekommt einen Hash für das Modul als zentrale Datenstruktur übergeben.

Dieser Hash wird im globalen Hash %modules gespeichert. $modules{$ModulName} wäre dabei der Hash für das Modul mit dem Namen $ModulName. Es handelt sich also nicht um den oben beschriebenen Hash der Geräteinstanzen sondern einen Hash, der je Modul Werte enthält, beispielsweise auch die Namen der Funktionen, die das Modul implementiert und die fhem.pl aufrufen soll. Die Initialize-Funktion setzt diese Funktionsnamen, in den Hash des Moduls:

$hash->{DefFn}      = "X_Define";
$hash->{UndefFn}    = "X_Undef";
$hash->{DeleteFn}   = "X_Delete";
$hash->{SetFn}      = "X_Set";
$hash->{GetFn}      = "X_Get";
$hash->{AttrFn}     = "X_Attr";
$hash->{NotifyFn}   = "X_Notify";
$hash->{ReadFn}     = "X_Read";
$hash->{ReadyFn}    = "X_Ready";
$hash->{ShutdownFn} = "X_Shutdown";

X ist wieder durch den Modulnamen ohne die vorangestellte Zahl zu ersetzen. Entsprechend können auch die Funktionen X_Read, X_Parse etc. durch Zuweisung an $hash->{ReadFn} etc. bekannt gemacht werden.

Darüber hinaus sollten die vom Modul unterstützten Attribute definiert werden:

$hash->{AttrList} =
  "do_not_notify:1,0 " . 
  "header " .
  $readingFnAttributes;

In Fhem.pl werden dann die entsprechenden Werte beim Aufruf eines attr-Befehls in die globale Datenstruktur $attr{$name}, z.B. $attr{$name}{header} für das Attribut header gespeichert. Falls im Modul weitere Aktionen oder Prüfungen beim Setzen eines Attributs nötig sind, dann kann wie im Beispiel oben die Funktion X_Attr implementiert und in der Initialize-Funktion bekannt gemacht werden.

Die Variable $readingFnAttributes, die im obigen Beispiel an die Liste der unterstützten Attribute angefügt wird, definiert Attributnamen, die dann verfügbar werden wenn das Modul zum Setzen von Readings die Funktionen readingsBeginUpdate, readingsBulkUpdate, readingsEndUpdate oder readingsSingleUpdate verwendet. In diesen Funktionen werden Attribute wie event-min-interval oder auch event-on-change-reading ausgewertet. Für Details hierzu siehe commandref.

Des weiteren ist es möglich, das Verhalten von Autocreate zu beeinflussen. x ist durch den Namen der Geräte zu ersetzen. Legt ihr Geräte mit dem Namen LaCrosse an, dann sollte x durch LaCrosse ersetzt werden.

  $hash->{AutoCreate} =
        { "x.*" => { ATTR => "event-min-interval:.*:300 event-on-change-reading:.*", 
                     FILTER => "%NAME", 
                     GPLOT => "temp4hum4:Temp/Hum,"} };
                     autocreateThreshold => "<count>:<timeout>"

Mit ATTR => können Vordefinierte Attribute beim Anlegen definiert werden. Der Wert von FILTER wird als Regex verwendet, wenn ein Filelog angelegt wird. Damit könnt ihr steuern, welche Events ins Filelog komme. Definiert ihr das Feld FILTER nicht, gebt jedoch andere Felder an, dann kann kein filelog mehr automatisch durch autocreate angelegt werden! Mit Hilfe von GPLOT kann ein Plot angelegt werden. Mit der Angabe definiert ihr, welcher GPLOT angelegt wird. Mittels autocreateThreshold wird beeinflusst, wie oft count(default 2) und in welchem Zeitabstand timeout (default 60 Sekunden) die gleiche Nachricht empfangen werden muss, damit ein Gerät per autocreate angelegt wird. Das Verhalten, kann vom Anwender mittels Attribut autocreateThreshold im device "autocreate" überschrieben werden.

Das Parsen der Parameter der define, get und set Kommandos sowie deren Übergabe an die DefFn, GetFn und SetFn lässt sich mit

$hash->{parseParams} = 1;

beeinflussen. Sobald es gesetzt ist wird automatisch parseParams aufgerufen und die an X_Define, X_Get und X_Set übergebenen Parameter ändern sich wie weiter unten beschrieben.

X_Define

Die Define-Funktion eines Moduls wird von Fhem aufgerufen wenn der Define-Befehl für ein Geräte ausgeführt wird und das Modul bereits geladen und mit der Initialize-Funktion initialisiert ist. Sie ist typischerweise dazu da, die übergebenen Parameter zu prüfen und an geeigneter Stelle zu speichern sowie einen Kommunikationsweg zum Gerät zu öffnen (z.B. TCP-Verbindung, USB-Schnittstelle o.ä.). Sie beginnt typischerweise mit:

sub X_Define($$)
{
	my ( $hash, $def ) = @_;
	my @a = split( "[ \t][ \t]*", $def );
	...

Als Übergabeparameter bekommt die Define-Funktion den Hash der Geräteinstanz sowie den Rest der Parameter, die im Befehl angegeben wurden. Welche und wie viele Parameter akzeptiert werden ist Sache dieser Funktion. Im obigen Beispiel wird alles nach dem übergebenen Hash in ein Array aufgeteilt und so können die vom Modul bzw. der Define-Funktion erwarteten Werte über das Array der Reihe nach verarbeitet werden:

my $name 	= $a[0];
my $url 	= $a[2];
my $inter	= 300;
if(int(@a) == 4) { 
	$inter = $a[3]; 
	if ($inter < 5) {
		return "interval too small, please use something > 5, default is 300";
	}
}

Damit die übergebenen Werte auch anderen Funktionen zur Verfügung stehen und an die jeweilige Geräteinstanz gebunden sind, werden die Werte typischerweise als Internals im Hash der Geräteinstanz gespeichert:

$hash->{url} 		= $url;
$hash->{Interval}	= $inter;

Nutzung von parseParams()

Zum Aufteilen und Parsen von $def lässt sich die Funktion parseParams verwenden um die einzelnen Argumente einfach zu parsen. Wenn in X_Initialize $hash->{parseParams} = 1; gesetzt wurde dann wird parseParams automatisch aufgerufen und X_Define ändert sich wie folgt:

sub X_Define($$$)
{
	my ( $hash, $a, $h ) = @_;
	...

Die genauen Möglichkeiten von parseParams sind in dem entsprechenden Artikel dokumentiert.

Nutzung von DevIo

Wenn eine physische Schnittstelle geöffnet werden soll und dann bei verfügbaren Eingabedaten eine Lese-Funktion von Fhem aufgerufen werden soll, dann kann man in der Define-Funktion die Funktion DevIo_OpenDev aufrufen, die sich um alles weitere kümmert. Sie öffnet die Schnittstelle und fügt den Filedeskriptor an die globale Liste offener Verbindungen (selectlist / readyfnlist) an. Damit kann Fhem in seiner Hauptschleife erkennen, von welchem Gerät Daten bereit stehen und die zuständigen Funktionen aufrufen:

my $ret = DevIo_OpenDev( $hash, 0, "X_DevInit" );

Die optionale Funktion X_DevInit wird zur weiteren Initialisierung der Verbindung von DevIo_OpenDev aufgerufen. Der zweite Übergabeparameter an DevIo_OpenDev (hier 0) steht für reopen und wird benötigt, da die Funktion auch aufgerufen wird, wenn ein USB-Geräte beispielsweise im Betrieb aus- und wieder eingesteckt wird. In diesem Fall wird die Funktion mit 1 aufgerufen.

X_Undef

Die Undef-Funktion wird aufgerufen wenn ein Gerät mit delete gelöscht wird oder bei der Abarbeitung des Befehls rereadcfg, der ebenfalls alle Geräte löscht und danach das Konfigurationsfile neu abarbeitet. Entsprechend müssen in der Funktion typische Aufräumarbeiten durchgeführt werden wie das saubere Schließen von Verbindungen oder das Entfernen von internen Timern sofern diese im Modul zum Pollen verwendet wurden (siehe später).

Zugewiesene Variablen im Hash der Geräteinstanz, Internals oder Readings müssen hier nicht gelöscht werden. In fhem.pl werden die entsprechenden Strukturen beim Löschen der Geräteinstanz ohnehin vollständig gelöscht.

Beispiel:

sub X_Undef($$)    
{                     
	my ( $hash, $name) = @_;       
	DevIo_CloseDev($hash);         
	RemoveInternalTimer($hash);    
	return undef;                  
}

X_Delete

Die Delete-Funktion ist das Gegenstück zur Define-Funktion und wird aufgerufen wenn ein Gerät mit delete gelöscht wird.

Wenn ein Gerät mittels delete gelöscht wird, wird zuerst die Undef-Funktion aufgerufen um offene Verbindungen abzubauen, anschließend wird die Delete-Funktion aufgerufen. Diese dient eher zum aufräumen von Dateien, welche durch das Modul evtl. für dieses Gerät spezifisch erstellt worden sind. Es geht hier also eher darum, alle Spuren sowohl im laufenden FHEM-Prozess, als auch Dateien oder Verbindungen zu löschen die mit diesem Gerät zu tun haben.

Dies kann z.B. folgendes sein:

Löschen von Dateien im Dateisystem die während der Nutzung dieses Geräts angelegt worden sind.
Lösen von evtl. Pairings mit dem physikalischen Gerät

Beispiel:

sub X_Delete($$)    
{                     
	my ( $hash, $name ) = @_;       

	# Löschen von Geräte-assoziiertem Temp-File
	unlink($attr{global}{modpath}."/FHEM/FhemUtils/$name.tmp";)
}

X_Get

Die Get-Funktion wird aufgerufen wenn der Fhem-Befehl get mit einem Gerät dieses Moduls ausgeführt wird. Mit get werden typischerweise Werte von einem Gerät abgefragt. Einige Module verwenden für diese Funktion einen Hash im Modul, der die möglichen get-Optionen mit zusätzlichen Werten definiert:

my %X_gets = (
	"TempSoll"	=> "XY",
	"Steilheit"	=> "Z"
);

In der Get-Funktion selbst werden dann die übergebenen Parameter gegen diesen Hash geprüft.

Beispiel:

sub X_Get($@)
{
	my ( $hash, $name, $opt, @a ) = @_;
	return "\"get $name\" needs at least one argument" unless(defined($opt)));

	if($opt eq "status") {
	   ...
	}
	elsif($opt eq "powser")
	{
	   ...
	}
	...
	else
	{
		return "Unknown argument $opt, choose one of " . join(" ", keys %X_gets;);
	}
}

Die Ausgabe der Meldung mit unknown ... choose one of ... ist dabei wichtig, da sie im GUI-Modul verwendet wird um die möglichen get-Optionen zu ermitteln und als Auswahl anzubieten. Im weiteren Verlauf der Ger-Funktion könnte man dann mit dem physischen Gerät kommunizieren und den gefragten Wert abfragen und diesen als Return-Wert der Get-Funktion zurückgeben.

Nutzung von parseParams()

Wenn in X_Initialize $hash->{parseParams} = 1; gesetzt wurde dann wird parseParams automatisch aufgerufen und X_Get ändert sich wie folgt:

sub X_Get($$$)
{
	my ( $hash, $a, $h ) = @_;
	...

Die genauen Möglichkeiten von parseParams sind in dem entsprechenden Artikel dokumentiert.

X_Set

Die Set-Funktion ist das Gegenteil zur Get-Funktion. Sie ist dafür gedacht, Werte zum physischen Gerät zu schicken. Falls nur interne Werte im Modul gesetzt werden sollen, so sollte statt Set die Attr-Funktion verwendet werden. Attribute werden bei Save-Config auch in der Fhem.cfg gesichert. Set-Befehle nicht.

Eine Set-Funktion ist ähnlich aufgebaut wie die Get-Funktion, sie bekommt jedoch nach dem Namen der Option auch den zu setzenden Wert übergeben.

Beispiel:

sub X_Set($@)
{
	my ( $hash, $name, $opt, @a ) = @_;
	return "\"set $name\" needs at least one argument" unless(defined($opt)));

	if($opt eq "status") {
	   ...
	}
	elsif($opt eq "powser")
	{
	   ...
	}
	...
	else
	{
		return "Unknown argument $opt, choose one of " . join(" ", keys %X_sets;);
	}
}

Nutzung von parseParams()

Wenn in X_Initialize $hash->{parseParams} = 1; gesetzt wurde dann wird parseParams automatisch aufgerufen und X_Set ändert sich wie folgt:

sub X_Set($$$)
{
	my ( $hash, $a, $h ) = @_;
	...

Die genauen Möglichkeiten von parseParams sind in dem entsprechenden Artikel dokumentiert.

Nutzung von FHEMWEB-Widgets

Das GUI-Modul FHEMWEB kann für die einzelnen Set-Optionen, die das Modul versteht, automatisch Eingabehilfen wie Drop-Down Boxen oder Slider erzeugen. In der Detailansicht der GUI kann der Anwender dann die jeweiligen Werte komfortabel auswählen. Dafür muss die Set-Funktion, wenn sie mit der Option ? aufgerufen wird, nicht nur einen Text mit "Unknwon ... choose one of ..." zurückgeben sondern den einzelnen Set-Optionen in diesem Rückgabetext nach einem Doppelpunkt entsprechende Zusatzinformationen anhängen. Meist prüft man in den Modulen gar nicht auf die Option ? sondern gibt generell bei unbekannten Optionen diesen Text zurück.

Beispiel:

	if(!defined($X_sets{$opt})) {
		return "Unknown argument $opt, choose one of mode:verbose,ultra,relaxed turbo:NoArg";
	}

Mit Kommata getrennte Werte ergeben eine Drop-Down Liste, mit der der User die Werte auswählen kann

timer:30,120,300
mode:verbose,ultra,relaxed

Wird kein Doppelpunkt zum Kommando angegeben, so wird eine Eingabezeile angezeigt, die die freie Eingabe eines Wertes erlaubt.

Man kann jedoch die Eingabe-/Auswahlmöglichkeiten durch Widgets vereinfachen. Dazu gibt man hinter dem Doppelpunkt einen Widgetnamen und widgetspezifische Parameter an. Es existieren mehrere solcher Widgets in FHEMWEB. Die gebräuchlichsten sind:

Zusatz	Beispiel	Beschreibung
noArg	`reset:noArg`	Es werden keine weiteren Argumente mehr benötigt. In so einem Fall wird bei der Auswahl keine Textbox oder ähnliches angezeigt, da keine weiteren Argumente für diesen Befehl notwendig sind.
slider:<min>,<step>,<max>	`dim:slider,0,1,100`	Es wird ein Schieberegler angezeigt um den Parameter auszuwählen. Dabei werden als Zusatzparameter Minimum, Schrittweite und Maximum angegeben.
colorpicker	`rgb:colorpicker,RGB`	es wird ein Colorpicker angezeigt, der dem Anwender die Auswahl einer Farbe ermöglicht. Bitte dazu auch den Wiki Artikel zum Colorpicker lesen: Color#Colorpicker
multiple	`group:multiple,Telefon,Multimedia,Licht,Heizung`	Es erscheint ein Auswahldialog, wo man verschiedene Werte durch klicken auswählen kann. Optional kann man in einem Freitext eigene Werte ergänzen. dieser Dialog wird bspw. bei der Raum-Auswahl (Attribut "room") oder der Gruppen-Auswahl (Attribut "group") in FHEMWEB genutzt.
sortable	`command:sortable,monday,tuesday,...`	Es erscheint ein Auswahldialog, wo man verschiedene Werte auswählen und sortieren kann. Man kann dabei Werte durch Klicken auswählen und durch Drag'n'Drop sortieren.

Es gibt noch weitere solcher Widgets. Eine genaue Auflistung dazu findet sich in der commandref unter widgetOverride zu FHEMWEB.

Hinweise

Damit in einer Eingabe bereits der aktuelle Wert vorbelegt bzw. in einer Auswahlliste der aktuelle Wert vorselektiert ist, muss es im Modul bzw. Gerät ein Reading mit dem gleichen Namen wie die Set-Option geben. Der Wert des gleichnamigen Readings wird dann als Vorbelegung / Vorselektion verwendet.
Bei den üblichen Kommandos wie on off sollte man auf noArg verzichten, da diese durch FHEMWeb automatisch in der Raumübersicht angezeigt werden. Wenn man hier noArg spezifiziert, so werden diese nicht neben dem Modul in der Raumübersicht angezeigt und der User muss sich diese vie webCmd dann erst selbst definieren, was natürlich unschön ist.
Der User kann sich in der Raumübersicht nach wie vor via webCmd eine entsprechende Steuerung anlegen.

X_Attr

Die Attr-Funktion implementiert Prüfungen der bei einem attr übergebenen Werte und eventuell zusätzliche Aktionen wenn ein Attribut gesetzt wird. Die Liste der möglichen Attribute wird in der X_Initialize-Funktion definiert (siehe oben). Fhem ruft bei einem Attr-Befehl die zuständige X-Attr-Funktion auf und wenn diese keine Fehlermeldung sondern undef zurückgibt, dann schreibt fhem.pl die bei attr angegebenen Werte in die jeweilige Datenstruktur $attr{$name}-> ...

Beispiel:

X_Attr(@)
{
	my ($cmd,$name,$aName,$aVal) = @_;
  	# $cmd can be "del" or "set"
	# $name is device name
	# aName and aVal are Attribute name and value
	if ($cmd eq "set") {
		if ($aName eq "Regex") {
			eval { qr/$aVal/ };
			if ($@) {
				Log3 $name, 3, "X: Invalid regex in attr $name $aName $aVal: $@";
				return "Invalid Regex $aVal";
			}
		}
	}
	return undef;
}

Zusätzlich ist es möglich auch übergebene Attributwerte zu normalisieren und korrigieren, indem man im Parameterhash den ursprünglichen Wert anpasst. Dies erfolgt im Beispiel über die Modifikation des Wertes mit Index 3 im Parameterarray, also $_[3].

Da das Attribut zum Zeitpunkt des Aufrufs der Attr-Funktion noch nicht gespeichert ist, wird der neue Wert zu diesem Zeitpunkt noch nicht via AttrVal() zurückgegeben. Erst, wenn die Attr-Funktion mit undef beendet ist, wird der neue Wert in FHEM gespeichert und steht dann via AttrVal() zur Verfügung.

Die Attr-Funktion bekommt nicht den Hash der Geräteinstanz übergeben, da sie ja auch keine Werte dort speichern muss, sondern den Befehl set oder del je nachdem ob ein Attribut gesetzt oder gelöscht wird, den Namen der Geräteinstanz sowie den Namen des Attributs und seinen Wert. Im obigen Beispiel wird für ein Attribut mit Namen Regex geprüft ob die Regex fehlerhaft ist. Falls sie ok ist, wird undef zurückgegeben und fhem.pl speichert den Wert des Attributs.

Falls man Attribute mit Platzhaltern definiert (Wildcard-Attribute), z.B. mit

    $hash->{AttrList} =
      "reading[0-9]*Name " .
    # usw.

dann können Anwender Attribute wie reading01Name, reading02Name etc. setzen. Leider funktioniert das bisher nicht durch Klicken, da Fhemweb nicht alle denkbaren Ausprägungen in einem Dropdown anbieten kann. Der Benutzer muß solche Attribute über den attr Befehl eintippen.

Man kann jedoch in der Attr-Funktion neu gesetzte Ausprägungen von Wildcard-Attributen an die gerätespezifische userattr-Variable anfügen. Dann können bereits gesetzte Attribute in Fhemweb durch Klicken ausgewählt und geändert werden. Dazu reicht ein Aufruf von

    addToDevAttrList($name, $aName);

in der Attr-Funktion wenn ein Attribut gesetzt wird.

X_Read

Die X_Read-Funktion wird aus der Hauptschleife von FHEM aus aufgerufen wenn das Gerät, für das das Modul zuständig ist, Daten bereit gestellt hat, die gelesen werden können. Im folgenden Beispiel wird über eine serielle Schnittstelle (beziehungsweise über einen USB-To-Seriell-Konverter) von einem angeschlossenen Gerät gelesen. Dazu werden die bisher verfügbaren Daten mit der Funktion DevIo_SimpleRead gelesen. Da die Übertragung möglicherweise noch nicht vollständig ist, kann es sein, dass kurz darauf die X_Read-Funktion wieder aufgerufen wird und ein weiterer Teil oder der Rest der Daten gelesen werden kann. Die Funktion muss daher prüfen ob schon alle erwarteten Daten angekommen sind und gegebenenfalls die bisher gelesenen Daten zwischenspeichern. Es bietet sich an, dies im Hash der Geräteinstanz zu tun. Im Beispiel ist dies $hash->{buffer} an den die jeweils gelesenen Daten angehängt werden bis die folgende Prüfung ein für das jeweilige Protokoll passendes Frame identifiziert.

sub X_Read($)
{
	my ($hash) = @_;
	my $name = $hash->{NAME};
	
	# read from serial device
	my $buf = DevIo_SimpleRead($hash);		
	return "" if ( !defined($buf) );

	# convert to hex string to make parsing with regex easier
	$hash->{buffer} .= unpack ('H*', $buf);	
	Log3 $name, 5, "Current buffer content: " . $hash->{buffer};

	# did we already get a full frame?
	if ($hash->{buffer} =~ "ff1002(.{4})(.*)1003(.{4})ff(.*)") 
	...

Die zu lesenden Nutzdaten können dann je nach Protokoll des Geräts beispielsweise an einer festgelegten Stelle im Frame (dann in $hash->{buffer}) stehen oder aus dem Kontext mit einem Regex-Match extrahiert werden und in Readings gespeichert werden (siehe unten).

X_Ready

Wird im Main-Loop aufgerufen falls das Modul in @readyfnlist existiert. Prüft, ob das Gerät Daten zum empfangen hat. Beim Initialisieren des Moduls sollte es sich in die Liste eintragen.

Weiterführende Informationen: #KommunikationvomGerätZuLogischenModulen

Beispiel:

sub X_Ready($)
{
	my ($hash) = @_;
	return DevIo_OpenDev($hash, 1, undef )
	  if ( $hash->{STATE} eq "disconnected" );

	# This is relevant for windows/USB only
	my $po = $hash->{USBDev};
	my ( $BlockingFlags, $InBytes, $OutBytes, $ErrorFlags ) = $po->status;
	return ( $InBytes > 0 );
}

X_Notify

Die X_Notify-Funktion wird aus der Funktion DoTrigger() in fhem.pl heraus aufgerufen sobald ein Modul Events erzeugt hat. Damit kann ein Modul auf Events anderer Module reagieren. Typische Beispiele sind dabei das FileLog-Modul oder das notify-Modul.

Die Notify-Funktion bekommt dafür zwei Hash-Referenzen übergeben: den Hash des eigenen Geräts und den Hash des Geräts, dass die Events erzeugt hat. Über den Hash des eigenen Geräts kann die Notify-Funktion beispielsweise auf die Internals oder Attribute des eigenen Geräts zugreifen. Über den Hash des Gerätes und der deviceEvents()-Funktion kann man auf die generierten Events zugreifen. Über den zweiten Parameter dieser Routine lässt sich bestimmen ob für das Reading state ein 'normales' Event (d.h. in der form state: <wert>) erzeugen soll (Wert: 1) oder ob z.b. aus Gründen der Rückwärtskompatibilität ein Event ohne state: erzeugt werden soll. Falls dem Anwender die Wahl des verwendeten Formats überlassen werden soll ist hierzu das addStateEvent-Attribut vorzusehen.

Der direkte Zugriff auf $hash->{CHANGED} ist nicht mehr zu empfehlen.

Beispiel:

sub X_Notify($$)
{
  my ($own_hash, $dev_hash) = @_;
  my $ownName = $own_hash->{NAME}; # own name / hash

  return "" if(IsDisabled($ownName)); # Return without any further action if the module is disabled

  my $devName = $dev_hash->{NAME}; # Device that created the events

  my $events = deviceEvents($dev_hash,1);
  return if( !$events );

  foreach my $event (@{$events}) {
    $event = "" if(!defined($event));

    # Examples:
    # $event = "readingname: value" 
    # or
    # $event = "INITIALIZED" (for $devName equal "global")
    #
    # processing $event with further code
  }
}

Begrenzung der Aufrufe auf bestimmte Geräte

Da die Notify-Funktion für jedes definierte Gerät mit all seinen Events aufgerufen wird, muss sie in einer Schleife jedesmal prüfen und entscheiden, ob es mit dem jeweiligen Event etwas anfangen kann. Ein Gerät, dass die Notify-Funktion implementiert, sieht dafür typischerweise einen regulären Ausdruck vor, welcher für die Filterung verwendet wird.

Wenn man nur gezielt von bestimmten Definitionen Events erhalten will, kann man diese auch in Form einer devspec in $hash->{NOTIFYDEV} angeben. Bspw. kann man in der Define-Funktion diesen Wert setzen. Dadurch wird die Notify-Funktion nur aufgerufen wenn eine der Definitionen, auf welche die devspec passt, ein Event erzeugt hat. Ein typischer Fall ist die Begrenzung von Events auf "global":

in der Define-Funktion:

$hash->{NOTIFYDEV} = "global";
$hash->{NOTIFYDEV} = "global,Definition_A,Definition_B";
$hash->{NOTIFYDEV} = "global,TYPE=CUL_HM";

Dies schont insbesondere bei grossen Installationen Ressourcen, da die Notify-Funktion nicht sämtliche Events, sondern nur noch Events der gewünschten Definitionen erhält. Dadurch erfolgen deutlich weniger Aufrufe der Notify-Funktion, was Systemressourcen schont.

Reihenfolge für den Aufruf der Notify-Funktion beeinflussen

Sobald ein Event ausgelöst wurde, stellt sich FHEM eine Liste aller relevanten Geräte-Hashes zusammen, welche via Notify-Funktion prüfen müssen, ob das Event relevant ist. Dabei wird die Liste nach $hash->{NTFY_ORDER} sortiert. Diese enthält ein Order-Präfix in Form einer Ganzzahl, sowie den Namen der Definition (Bsp: 50-Lampe_Wohnzimmer). Dadurch kann man jedoch nicht sicherstellen, dass Events von bestimmten Modulen zuerst verarbeitet werden.

Wenn das eigene Modul bei der Eventverarbeitung gegenüber den anderen Modulen eine bestimmte Reihenfolge einhalten muss, kann man in der Initialize-Funktion durch Setzen von $hash->{NotifyOrderPrefix} diese Reihenfolge beeinflussen. Standardmäßig werden Module immer mit einem Order-Präfix von "50-" in FHEM registriert. Durch die Veränderung dieses Präfixes kann man das eigene Modul in der Reihenfolge gegenüber anderen Modulen bei der Eventverarbeitung beeinflussen.

Beispiel:

sub X_Initialize($)
{
	my ($hash) = @_;
	
	...
	
	$hash->{NotifyOrderPrefix} = "45-"  # Alle Definitionen des Moduls X werden bei der Eventverarbeitung zuerst geprüft
	
	# oder...
	
	$hash->{NotifyOrderPrefix} = "55-"  # Alle Definitionen des Moduls X werden bei der Eventverarbeitung als letztes geprüft

Da dieses Präfix bei eventverarbeitenden Definitionen in $hash->{NTFY_ORDER} dem Definitionsnamen vorangestellt wird bewirkt es bei einer normalen aufsteigenden Sortierung nach $hash->{NTFY_ORDER} eine veränderte Reihenfolge. Alle Module die in der Initialize-Funktion nicht $hash->{NotifyOrderPrefix} explizit setzen, werden mit "50-" als Standardwert vorbelegt.

X_DbLog_splitFn

Mit der DbLog_SplitFn kann der Modulautor selbst festlegen, wie die Events des Moduls in die Bestandteile Reading/Value/Unit zerlegt werden um ein korrektes Logging per DbLog zu gewährleisten.
Eingangsparameter:
1. Das generierte Event
2. das eventgenerierende Device
Rückgabewerte: Array: Reading/Value/Unit

Beispiel:

sub X_DbLog_splitFn($$)
{
	my ($event, $device) = @_;
	my ($reading, $value, $unit);
        my $hash = $defs{$device}

	if($event =~ m/temperature/) {
	   $reading = 'temperature';
	   $value = substr($event,12,4);
	   $unit = '°C';
	}   
        
        return ($reading, $value, $unit);
}

X_Shutdown

Mit der X_Shutdown Funktion kann ein Modul bei einem Shutdown von FHEM die geöffneten Ressourcen schließen.
Eingangsparameter: Der $hash einer Modul-Instanz

Beispiel:

sub X_Shutdown($)
{
	my ($hash) = @_;

	DevIo_CloseDev($hash);
        return undef;
}

Pollen von Geräten

Wenn Geräte von sich aus keine Informationen senden sondern abgefragt werden müssen, kann man im Modul die Funktion InternalTimer verwenden. Man übergibt ihr den Zeitpunkt für den nächsten Aufruf, den Namen der Funktion, die aufgerufen werden soll, den zu übergebenden Parameter und ein Flag ob der erste Aufruf verzögert werden soll falls die Initialiserung des Geräts noch nicht abgeschlossen ist. Als zu übergebender Parameter wird üblicherweise der Hash der betroffenen Geräteinstanz verwendet. Damit hat die aufgerufene Funktion Zugriff auf alle wichtigen Daten der Geräteinstanz. Eventuell zusätzlich benötigte Werte können einfach als weitere Internals über den Hash zugänglich gemacht werden.

Beispielsweise könnte man für das Abfragen eines Geräts in der Define-Funktion den Timer folgendermassen setzen:

# initial request after 2 secs, there timer is set to interval for further update
InternalTimer(gettimeofday()+2, "X_GetUpdate", $hash, 0);

in der Funktion X_GetUpdate selbst wird dann der Timer neu gesetzt, so dass nach einem Intervall die Funktion erneut aufgerufen wird:

sub X_GetUpdate($)
{
	my ($hash) = @_;
	my $name = $hash->{NAME};
	InternalTimer(gettimeofday()+$hash->{Interval}, "X_GetUpdate", $hash, 1);
	Log3 $name, 4, "X: GetUpdate called ...";

Im weiteren Verlauf der Funktion könnte man dann das Gerät abfragen und die abgefragten Werte in Readings speichern. Falls das Abfragen der Werte jedoch zu einer Verzögerung und damit zu einer Blockade von FHEM führen kann, ist es möglich, in der GetUpdate-Funktion nur die Aufforderung zum Senden bestimmter Daten an das angeschlossene Gerät zu senden und dann das Lesen über die oben beschriebene Read-Funktion zu implementieren, die beim Anstehen von Daten aufgerufen wird.

Eine genaue Beschreibung der Timer-Funktion gibt es hier im Wiki

Logging / Debugging

Um Innerhalb eines Moduls eine Protokollmeldung in die Fhem-Logdatei zu schreiben, wird die Funktion Log3 aufgerufen:

Log3 $name, 3, "X: Problem erkannt ...";

Die Parameter der Funktion Log3 sind der Name oder der Hash der Geräteinstanz, das Verbose-Level, in dem die Meldung sichtbar sein soll und die Meldung selbst. Den Namen der Geräteinstanz kann man in den Funktionen, die den Hash übergeben bekommen einfach aus diesem Hash nehmen:

my $name = $hash->{NAME};

Um für ein neues Modul das Verbose-Level zu erhöhen, ohne gleich für das Gesamte FHEM alle Meldungen zu erzeugen kann man den Befehl attr gerätename verbose verwenden. Beispielsweise attr PM verbose 5

Damit bietet es sich an im Modul Meldungen, die im normalen Betrieb nicht benötigt werden, beim Aufruf von Log3 mit dem Level 4 oder 5 anzugeben. Wenn man dann bei der Fehlersuche mehr Meldungen sehen möchte, erhöht man mit attr X verbose das Level für das betroffene Gerät.

Eine genaue Beschreibung der Log-Funktion gibt es unter hier im Wiki.

Zweistufiges Modell für Module

siehe auch

Das zweistufige Modell besteht aus

physisches Modul - z.B. für CUL (00_CUL.pm), der mehrer Protokolle empfängt, u.a. FS20
logische Modul(e) - z.B. das Protokoll FS20 (10_FS20.pm)

Das physische Modul öffnet die Datenverbindung zum Gerät.

Kommunikation vom Gerät zu den logischen Modulen

Die X_Read-Funktion wird aus der Hauptschleife von fhem.pl aufgerufen sobald das Gerät, für welche das Modul zuständig ist, Daten zum Lesen bereit gestellt hat.

Unter Windows funktioniert die Prüfung via select() nur für Geräte, die via TCP verbunden sind. Für alle anderen Verbindungsarten (z.B. seriell) ist eine X_Ready-Funktion von Nöten, die 10x pro Sekunde das Gerät abfrägt und "true" zurück gibt, sollten Daten bereit stehen.

Die X_Read-Funktion stellt sicher, dass die Daten

komplett (in der Regel über einen internen Puffer in $hash) und
korrekt (z.B. via Regex)

sind und ruft die globale Funktion Dispatch() mit einer kompletten Nachricht auf.

Dispatch() sucht nach einer passenden Definition via $hash->{Clients} in physischen Definitionen und $hash->{Match} in allen passenden logischen Definitionen und ruft X_Parse in den gefundenen Modulen auf. Sofern keine passende Defintion gefunden wurde um die Nachricht zu verarbeiten, wird in der MatchList des Moduls der physischen Definition gesucht, welche bei der Initialisierung des Moduls via X_Initialize übergeben wurde ($hash->{MatchList}). Sollte es darin ein Modul geben, was diese Art von Nachricht verarbeiten kann, so wird versucht dieses Modul zu laden und eine neue Definition via Autocreate-Mechanismus anzulegen.

X_Parse

interpretiert die übergebene Nachricht
setzt alle Readings via readings*update()-Funktionen
gibt den Namen der logischen Definition zurück, welches die Nachricht verarbeitet hat

Es findet während der Verarbeitung einer Nachricht durch Dispatch() keine sofortige Eventverarbeitung statt, wenn die readings*update Funktionen innerhalb von X_Parse aufgerufen werden. (Im Gegensatz zum direkten Aufrufen der readings*update Funktionen ohne vorhergehendes Dispatch() )

Dispatch() triggert das Event-Handling für das von X_Parse zurückgegebene logische Device selbstständig.

Kommunikation von den logischen Modulen zum Gerät

Um von einem logischen Modul an ein physisches Gerät zu senden, wird im logischen Modul das Attribut IODev mit dem namen des physischen Devices gesetzt. Der Befehl AssignIoPort($hash); in der X_Define-Funktion des logischen Devices erledigt das.

Als Befehl zum Schreiben vom logischen ins physische Gerät soll IOWrite() verwendet werden. IOWrite() ruft im physischen Gerät die X_Write-Funktion auf.

Wenn es keine direkte Kommunikation zwischen dem logischen und dem physischen Gerät gibt(keine direkten Aufrufe von Funktionen, kein direktes überprüfen von $hash Werten,...) so können die Module hintereinander geschaltet werden (z.B. für Routerfunktionen wie in RFR) oder mittels FHEM2FHEM:RAW zwei Fhem Installationen verbunden werden und die logischen Devices werden dennoch funktionieren.

Ergänzende Hinweise

Die Wahl der vorangestellten Nummer für den Dateinamen eines neuen Moduls hat keine Bedeutung mehr, es sei denn die Nummer ist 99. Module, die mit 99_ beginnen, werden von FHEM automatisch geladen. Module mit einer anderen Nummer nur wenn ein define-Befehl dafür sorgt, dass das Modul geladen wird.

Wenn ein Modul Initialisierungsdaten benötigt, sollten diese im Modul selbst enthalten sein. Eine zusätzliche Datei oder sogar ein Unterverzeichnis mit mehreren Dateien ist bei FHEM nicht üblich und sollte bei Modulen, die mit FHEM ausgeliefert werden nur in Rücksprache mit Rudolf König angelegt werden, da sie sonst bei einem Update nicht verteilt werden.

Weitere Informationen

Wenn man weitere Details wissen möchte, ist ein erster sinnvoller Schritt ein Blick in die Datei fhem.pl. Dort sieht man im Perl-Code wie die Module aufgerufen werden, was vorher passiert und was danach. Am Anfang der Datei (ca. ab Zeile 130) findet man beispielsweise eine Liste der globalen Variablen, die den Modulen zur Verfügung stehen sowie Details zu den wichtigen Hashes %modules und %defs. Wer mit Perl noch nicht so gut klar kommt, dem hilft eventuell ein Blick auf die Perldoc Website[1] oder in das Perl-Buch seiner Wahl. Auch die FHEM Commandref [2] sollte nicht unterschätzt werden. Es stehen oft mehr interessante Details auch für Modulentwickler darin als man zunächst vermuten könnte.

"Hello World" Beispiel

98_Hello.pm

package main;
use strict;
use warnings;

my %Hello_gets = (
	"whatyouwant"	=> "can't",
	"whatyouneed"	=> "try sometimes",
	"satisfaction"  => "no"
);

sub Hello_Initialize($) {
    my ($hash) = @_;

    $hash->{DefFn}      = 'Hello_Define';
    $hash->{UndefFn}    = 'Hello_Undef';
    $hash->{SetFn}      = 'Hello_Set';
    $hash->{GetFn}      = 'Hello_Get';
    $hash->{AttrFn}     = 'Hello_Attr';
    $hash->{ReadFn}     = 'Hello_Read';

    $hash->{AttrList} =
          "formal:yes,no "
        . $readingFnAttributes;
}

sub Hello_Define($$) {
    my ($hash, $def) = @_;
    my @param = split('[ \t]+', $def);
    
    if(int(@param) < 3) {
        return "too few parameters: define <name> Hello <greet>";
    }
    
    my $hash->{name}  = $param[0];
    my $hash->{greet} = $param[2];
    
    return undef;
}

sub Hello_Undef($$) {
    my ($hash, $arg) = @_; 
    # nothing to do
    return undef;
}

sub Hello_Get($@) {
	my ($hash, @param) = @_;
	
	return '"get Hello" needs at least one argument' if (int(@param) < 2);
	
	my $name = shift @param;
	my $opt = shift @param;
	if(!$Hello_gets{$opt}) {
		my @cList = keys %Hello_gets;
		return "Unknown argument $opt, choose one of " . join(" ", @cList);
	}
	
	if($attr{$name}{formal} eq 'yes') {
	    return $Hello_gets{$opt}.', sir';
    }
	return $Hello_gets{$opt};
}

sub Hello_Set($@) {
	my ($hash, @param) = @_;
	
	return '"set Hello" needs at least one argument' if (int(@param) < 2);
	
	my $name = shift @param;
	my $opt = shift @param;
	my $value = join("", @param);
	
	if(!defined($Hello_gets{$opt})) {
		my @cList = keys %Hello_gets;
		return "Unknown argument $opt, choose one of " . join(" ", @cList);
	}
    $hash->{STATE} = $Hello_gets{$opt} = $value;
    
	return "$opt set to $value. Try to get it.";
}


sub Hello_Attr(@) {
	my ($cmd,$name,$attr_name,$attr_value) = @_;
	if($cmd eq "set") {
        if($attr_name eq "formal") {
			if($attr_value !~ /^yes|no$/) {
			    my $err = "Invalid argument $attr_value to $attr_name. Must be yes or no.";
			    Log 3, "Hello: ".$err;
			    return $err;
			}
		} else {
		    return "Unknown attr $attr_name";
		}
	}
	return undef;
}

1;

=pod
=begin html

<a name="Hello"></a>
<h3>Hello</h3>
<ul>
    <i>Hello</i> implements the classical "Hello World" as a starting point for module development. 
    You may want to copy 98_Hello.pm to start implementing a module of your very own. See 
    <a href="http://www.fhemwiki.de/wiki/DevelopmentModuleIntro">DevelopmentModuleIntro</a> for an 
    in-depth instruction to your first module.
    <br><br>
    <a name="Hellodefine"></a>
    <b>Define</b>
    <ul>
        <code>define &lt;name&gt; Hello &lt;greet&gt;</code>
        <br><br>
        Example: <code>define HELLO Hello TurnUrRadioOn</code>
        <br><br>
        The "greet" parameter has no further meaning, it just demonstrates
        how to set a so called "Internal" value. See <a href="http://fhem.de/commandref.html#define">commandref#define</a> 
        for more info about the define command.
    </ul>
    <br>
    
    <a name="Helloset"></a>
    <b>Set</b><br>
    <ul>
        <code>set &lt;name&gt; &lt;option&gt; &lt;value&gt;</code>
        <br><br>
        You can <i>set</i> any value to any of the following options. They're just there to 
        <i>get</i> them. See <a href="http://fhem.de/commandref.html#set">commandref#set</a> 
        for more info about the set command.
        <br><br>
        Options:
        <ul>
              <li><i>satisfaction</i><br>
                  Defaults to "no"</li>
              <li><i>whatyouwant</i><br>
                  Defaults to "can't"</li>
              <li><i>whatyouneed</i><br>
                  Defaults to "try sometimes"</li>
        </ul>
    </ul>
    <br>

    <a name="Helloget"></a>
    <b>Get</b><br>
    <ul>
        <code>get &lt;name&gt; &lt;option&gt;</code>
        <br><br>
        You can <i>get</i> the value of any of the options described in 
        <a href="#Helloset">paragraph "Set" above</a>. See 
        <a href="http://fhem.de/commandref.html#get">commandref#get</a> for more info about 
        the get command.
    </ul>
    <br>
    
    <a name="Helloattr"></a>
    <b>Attributes</b>
    <ul>
        <code>attr &lt;name&gt; &lt;attribute&gt; &lt;value&gt;</code>
        <br><br>
        See <a href="http://fhem.de/commandref.html#attr">commandref#attr</a> for more info about 
        the attr command.
        <br><br>
        Attributes:
        <ul>
            <li><i>formal</i> no|yes<br>
                When you set formal to "yes", all output of <i>get</i> will be in a
                more formal language. Default is "no".
            </li>
        </ul>
    </ul>
</ul>

=end html

=cut

Der HTML-Code zwischen den Tags =pod und =cut dient zur Generierung der commandref.html. Der HTML-Inhalt wird automatisch beim Verteilen des Moduls im Rahmen des Update-Mechanismus aus jedem Modul extrahiert und daraus die Commandref in verschiedenen Sprachen erstellt. Eine detaillierte Beschreibung wie ein Commandref-Abschnitt in einem Modul definiert wird, siehe: Guidelines zur Dokumentation

Noch zu beschreiben

Zweistufiges Modell für Module
Funktion X_State_Fn: Thema, siehe auch DevelopmentState
FW_summaryFn (wird von FHEMWEB aufgerufen fuer Raum-Uebersicht)
FW_detailFn (wird von FHEMWEB aufgerufen fuer Detail-Ansicht)
DevIO
AsyncOutputFn / asyncOutput
SetExtensions / SetExtensionsCancel
ExceptFn (gleiche wie ReadFn aber EXCEPT_FD anstelle von FD)
FingerprintFn
ParseFn